Implement personal callback for Ipopt solver

[ocots]

Is it possible to get access to the current iterate of Ipopt solver in order to define its own callback?

The get_curr_iterate function of Ipopt solver has been wrapped in the Ipopt.jl.

Is it possible to define an ADNLPModel and then solve with Ipopt solver from NLPModelsIpopt.jl with a personal callback?

cb = (nlp, solver, stats) -> begin
    println(solver.x)
end
nlp = ADNLPModel(...)
sol = ipopt(nlp, callback=cb)

[tmigot]

Short answer: Yes !

The longer answer, now.

(temp) pkg> st
      Status `~/temp/Project.toml`
  [54578032] ADNLPModels v0.5.1
  [b6b21f68] Ipopt v1.2.0 `https://github.com/jump-dev/Ipopt.jl#master`
  [a4795742] NLPModels v0.19.2
  [f4238b75] NLPModelsIpopt v0.10.0

What follows only works with the master branch of Ipopt (so it will need Ipopt > 1.2.0).

In the unit tests, there is the following example that give an example of a simple callback:

using Test, ADNLPModels, Ipopt, NLPModelsIpopt
function callback(alg_mod, iter_count, args...)
    return iter_count < 1
  end
  nlp = ADNLPModel(x -> (x[1] - 1)^2 + 100 * (x[2] - x[1]^2)^2, [-1.2; 1.0])
  stats = ipopt(nlp, tol = 1e-12, callback = callback, print_level = 0)
  @test stats.status == :user
  @test stats.solver_specific[:internal_msg] == :User_Requested_Stop
  @test stats.iter == 1
  @test stats.elapsed_time > 0

However, contrary to the other JSO-solvers, the signature of the callback function is different here, see https://github.com/jump-dev/Ipopt.jl/ . Moreover, for your need, you will have to use the IpoptSolver structure explicitly, i.e. no longer use ipopt(nlp) but the following:

nlp = ADNLPModel(x -> (x[1] - 1)^2 + 100 * (x[2] - x[1]^2)^2, [-1.2; 1.0])
solver = IpoptSolver(nlp)
stats = solve!(solver, nlp, tol = 1e-12, callback = callback, print_level = 0)

Then, it is possible to use Ipopt.GetIpoptCurrentIterate (the same could be achieved with Ipopt.GetIpoptCurrentViolations) as follows:

function my_callback(
   alg_mod::Cint,
   iter_count::Cint,
   obj_value::Float64,
   inf_pr::Float64,
   inf_du::Float64,
   mu::Float64,
   d_norm::Float64,
   regularization_size::Float64,
   alpha_du::Float64,
   alpha_pr::Float64,
   ls_trials::Cint,
)
  problem = solver.problem
   Ipopt.GetIpoptCurrentIterate(
    problem,
    false,
    problem.n,
    problem.x,
    problem.mult_x_L,
    problem.mult_x_U,
    problem.m,
    problem.g,
    problem.mult_g,
)
  @show problem.x
   return true
end
nlp = ADNLPModel(x -> (x[1] - 1)^2 + 100 * (x[2] - x[1]^2)^2, [-1.2; 1.0])
solver = IpoptSolver(nlp)
stats = solve!(solver, nlp, tol = 1e-12, callback = my_callback, print_level = 0)

which returns

julia> stats = solve!(solver, nlp, tol = 1e-12, callback = my_callback, print_level = 0)
problem.x = [-1.2, 1.0]
problem.x = [-1.1752808988764045, 1.3806741573033707]
problem.x = [-0.932981427619827, 0.8112106557969998]
problem.x = [-0.7825400789708409, 0.5897363758123642]
problem.x = [-0.45999711906991914, 0.1075633885709778]
problem.x = [-0.39304563414149096, 0.15000236918356524]
problem.x = [-0.20941190910198323, 0.006770126701260648]
problem.x = [-0.06571902139586336, -0.01632865620409363]
problem.x = [0.1420425451701524, -0.022988783903550216]
problem.x = [0.23110719756117143, 0.04547802445904528]
problem.x = [0.3797428192164215, 0.11814580456882662]
problem.x = [0.47959488970127534, 0.22004082224746624]
problem.x = [0.6534058298068488, 0.3967289355251934]
problem.x = [0.7026236342925682, 0.4912575791881022]
problem.x = [0.8027855344433674, 0.6332210119305072]
problem.x = [0.863490808104559, 0.7419312454307843]
problem.x = [0.9420786864446876, 0.8813361968313452]
problem.x = [0.9679918174709445, 0.9363366683311184]
problem.x = [0.996210310759015, 0.9916386998991243]
problem.x = [0.9994793790596457, 0.9989483423579008]
problem.x = [0.9999988896181278, 0.9999975093462682]
problem.x = [0.9999999999400667, 0.9999999998789006]
problem.x = [1.0, 1.0]
"Execution stats: first-order stationary"

[tmigot]

It would be great to be able to do:

cb = (nlp, solver, stats) -> begin
    println(solver.x)
end

with ipopt as well, I will mark it as an issue.

[ocots]

Many thanks for the response.

This will be very useful for the development of our optimal control solver package OptimalControl.jl. We will replace the Ipopt callback, for instance in this example.

I note the fact that we have to change our call to the solver, here for instance.

[tmigot]

Great! Don't hesitate if there are any problems with this.

If you need more sophisticated callback, I would recommend switching to a solver implemented in Julia such as Percival.jl for instance.