Add R support

I use the original work from the PRs #45 (Jen-Chieh Shen, @jcs090218,
jcs090218@gmail.com) and #104 (Shuguang Sun, @ShuguangSun,
shuguang79@qq.com); rebased against master and updated the submodule to
the latest version.

Also, I added a changelog entry.

Author: maikol-solis

.gitmodules

@@ -222,4 +222,10 @@
 	url = https://github.com/WhatsApp/tree-sitter-erlang
 	branch = main
 	update = none
-	ignore = dirty
+	ignore = dirty
+[submodule "repos/r"]
+	path = repos/r
+	url = https://github.com/r-lib/tree-sitter-r.git
+	branch = master
+	update = none
+	ignore = dirty

CHANGELOG.md

@@ -1,6 +1,8 @@
 # Changelog
 
 ## Unreleased
+- Add `R` grammar
+
 
 ## 0.12.5 - 2022-11-14
 - Add `erlang` grammar

queries/r/highlight.scm

@@ -0,0 +1,128 @@
+; highlights.scm
+
+
+; Literals
+
+(integer) @number
+
+(float) @float
+
+(complex) @number
+
+(string) @string
+(string (escape_sequence) @string.escape)
+
+(comment) @comment
+
+(identifier) @variable
+
+(formal_parameters (identifier) @parameter)
+(formal_parameters (default_parameter (identifier) @parameter))
+
+; Operators
+[
+ "="
+ "<-"
+ "<<-"
+ "->>"
+ "->"
+] @operator
+
+(unary operator: [
+  "-"
+  "+"
+  "!"
+  "~"
+] @operator)
+
+(binary operator: [
+  "-"
+  "+"
+  "*"
+  "/"
+  "^"
+  "<"
+  ">"
+  "<="
+  ">="
+  "=="
+  "!="
+  "||"
+  "|"
+  "&&"
+  "&"
+  ":"
+  "~"
+] @operator)
+
+[
+  "|>"
+  (special)
+] @operator
+
+(lambda_function "\\" @operator)
+
+[
+ "("
+ ")"
+ "["
+ "]"
+ "{"
+ "}"
+] @punctuation.bracket
+
+(dollar "$" @operator)
+
+(subset2
+ [
+  "[["
+  "]]"
+ ] @punctuation.bracket)
+
+[
+ "in"
+ (dots)
+ (break)
+ (next)
+ (inf)
+] @keyword
+
+[
+  (nan)
+  (na)
+  (null)
+] @type.builtin
+
+[
+  "if"
+  "else"
+  "switch"
+] @conditional
+
+[
+  "while"
+  "repeat"
+  "for"
+] @repeat
+
+[
+  (true)
+  (false)
+] @boolean
+
+"function" @keyword.function
+
+(call function: (identifier) @function)
+(default_argument name: (identifier) @parameter)
+
+
+(namespace_get function: (identifier) @method)
+(namespace_get_internal function: (identifier) @method)
+
+(namespace_get namespace: (identifier) @namespace
+ "::" @operator)
+(namespace_get_internal namespace: (identifier) @namespace
+ ":::" @operator)
+
+; Error
+(ERROR) @error

queries/r/locals.scm

@@ -0,0 +1,11 @@
+; locals.scm
+
+(function_definition) @local.scope
+
+(formal_parameters (identifier) @local.definition)
+
+(left_assignment name: (identifier) @local.definition)
+(equals_assignment name: (identifier) @local.definition)
+(right_assignment name: (identifier) @local.definition)
+
+(identifier) @local.reference

repos/r

@@ -109,6 +109,7 @@ See `tree-sitter-langs-repos'."
                 (elm-mode        . elm)
                 (elixir-mode     . elixir)
                 (erlang-mode     . erlang)
+                (ess-r-mode      . r)
                 (go-mode         . go)
                 (haskell-mode    . haskell)
                 (hcl-mode        . hcl)