The option `interactive.nodes.node.nixpkgs.overlays' is defined multiple times (NixOS tests)

[bladyjoker]

In my NixOS test I'm trying to setup the private testnet node.

{inputs, pkgs, ...}:
{
  name = "NixOS test";

  nodes = {
    node = {
      imports = [
        inputs.cardano-nix.nixosModules.private-testnet-node
      ];
      cardano = {
        private-testnet-node.enable = true;
      };
    };


  };

  testScript = ''
  start_all()

  node.wait_for_unit("cardano-node.service")
  '';
}

However I keep getting

       error: The option `interactive.nodes.node.nixpkgs.overlays' is defined multiple times while it's expected to be unique.
       nixpkgs.overlays is set to read-only
       Definition values:
       - In `/nix/store/jqxk652ln98g0glsymaxqmlsrfns1whi-source/modules/private-testnet-node.nix':
           [
             <function>
           ]
       - In `/nix/store/dzwwydggypqg4p8r6if5zdaqyzhsxjkd-source/nixos/modules/misc/nixpkgs/read-only.nix':
           [
             <function>
             <function>
             <function>
             <function>
           ...
       Use `lib.mkForce value` or `lib.mkDefault value` to change the priority on any of these definitions.

[bladyjoker]

I suggest to have a testsuite for cardano.nix in a separate repository to provide a realistic test but also to serve as documentation on how to work with cardano.nix (to avoid potential implicit/hidden configuration difference).

[bladyjoker]

flake.nix

    nixpkgs.follows = "haskellNix/nixpkgs-unstable";
    cardano-nix.url = "github:mlabs-haskell/cardano.nix/v1.2.0";

I tried

   cardano-nix.inputs.nixpkgs.follows = "nixpkgs";

But no game!

[aciceri]

Try this:

{
  description = "Private testnet test";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    cardano-nix.url = "github:mlabs-haskell/cardano.nix";
  };

  outputs = inputs @ {flake-parts, ...}:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = ["x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin"];

      perSystem = {
        pkgs,
        ...
      }: {
        packages.default = pkgs.nixosTest {
          name = "NixOS test";

          nodes = {
            node = {
              imports = [
                inputs.cardano-nix.nixosModules.default
              ];
              cardano = {
                private-testnet-node.enable = true;
              };
            };
          };

          testScript = ''
            start_all()

            node.wait_for_unit("cardano-node.service")
          '';
        };
      };
    };
}

I can succesfully run nix build.

[bladyjoker]

https://nixos.org/manual/nixpkgs/unstable/#tester-runNixOSTest

A helper function that behaves exactly like the NixOS runTest, except it also assigns this Nixpkgs package set as the pkgs of the test and makes the nixpkgs.* options read-only.

Such a face palm!