Add some tests and a simple test runner

Author: shesek

src/stdlib/stdlib.minsc

@@ -69,3 +69,15 @@ fn _debug_nonfn($v) = if !isFunction($v) then debug($v) else $v;
 
 dyn fn log::env($label) = log("variables:\n----\n" + env::pretty() + "\n----");
 dyn fn log::debug_env($label) = log("variables:\n----\n" + env::debug() + "\n----");
+
+// Testing
+T = [];
+dyn fn test($topic, $test) {
+  T = T + [ $topic ];
+  $indent = if len(T) > 1 then join(fillArray(len(T)-1, "··"), "")+" " else "";
+  print("[TEST] " + $indent + join(T, " · "));
+  t::assert(if isFunction($test) then $test(T) else $test);
+}
+dyn fn t::assert($bool) = $bool || throw("["+last(T)+"] Assertion failed");
+dyn fn t::eq($a, $b) = ($a == $b) || throw("["+last(T)+"] Not equal: "+$a+" != "+$b);
+it = test;

tests/keys.minsc

@@ -0,0 +1,66 @@
+test("Keys", |T| {
+  test("Key generation & byte encoding", |T| {
+    $sk = xpriv::rand();
+    $pk = pubkey($sk);
+
+    t::eq(typeof($sk), "seckey");
+    t::eq(len(bytes($sk)), 78);
+    t::eq(seckey(bytes($sk)), $sk);
+
+    t::eq(typeof($pk), "pubkey");
+    t::eq(len(bytes($pk)), 78);
+    t::eq(pubkey(bytes($pk)), $pk)
+  });
+
+  test("Signing & Verification", |T| {
+    $sk = xpriv::rand(), $pk = pubkey($sk);
+    $H1 = hash::sha256("Hello"), $H2 = hash::sha256("Hello2");
+
+    test("ECDSA", |T| {
+      t::assert(ecdsa::verify($pk, $H1, ecdsa::sign($sk, $H1)));
+      t::assert(!ecdsa::verify($pk, $H2, ecdsa::sign($sk, $H1)));
+
+      it("Is deterministic (RFC 6979)", |T|
+        t::eq(ecdsa::sign($sk, $H1), ecdsa::sign($sk, $H1)));
+
+      it("Uses DER by default", len(ecdsa::sign($sk, $H1)) >= 70); // 70-73
+
+      it("Supports compact encoding", |T|
+        t::eq(len(ecdsa::sign($sk, $H1, true)), 64));
+    });
+
+    test("Schnorr", |T| {
+      t::assert(schnorr::verify($pk, $H1, schnorr::sign($sk, $H1)));
+      t::assert(!schnorr::verify($pk, $H1, schnorr::sign($sk, $H2)));
+
+      it("Is deterministic without aux_rand", |T| {
+        t::eq(schnorr::sign($sk, $H1), schnorr::sign($sk, $H1));
+        t::assert(schnorr::sign($sk, $H1, true) != schnorr::sign($sk, $H1, true));
+      })
+    })
+  });
+
+
+  test("BIP32 Test Vectors", |T| {
+      mainnet = _$$_RECKLESSLY_RISK_MY_BITCOINS_$$_;
+
+      test("Test 1", |T| {
+        $sk = xpriv::from_seed(0x000102030405060708090a0b0c0d0e0f, mainnet);
+        $pk = pubkey($sk);
+
+        t::eq($sk, xprv9s21ZrQH143K3QTDL4LXw2F7HEK3wJUD2nW2nRk4stbPy6cq3jPPqjiChkVvvNKmPGJxWUtg6LnF5kejMRNNU3TGtRBeJgk33yuGBxrMPHi);
+        t::eq($pk, xpub661MyMwAqRbcFtXgS5sYJABqqG9YLmC4Q1Rdap9gSE8NqtwybGhePY2gZ29ESFjqJoCu1Rupje8YtGqsefD265TMg7usUDFdp6W1EGMcet8);
+
+        t::eq(bytes($sk), 0x0488ade4000000000000000000873dff81c02f525623fd1fe5167eac3a55a049de3d314bb42ee227ffed37d50800e8f32e723decf4051aefac8e2c93c9c5b214313817cdb01a1494b917c8436b35);
+        t::eq(bytes($pk), 0x0488b21e000000000000000000873dff81c02f525623fd1fe5167eac3a55a049de3d314bb42ee227ffed37d5080339a36013301597daef41fbe593a02cc513d0b55527ec2df1050e2e8ff49c85c2);
+      });
+
+      test("Test 2", |T| {
+        $sk = xpriv::from_seed(0xfffcf9f6f3f0edeae7e4e1dedbd8d5d2cfccc9c6c3c0bdbab7b4b1aeaba8a5a29f9c999693908d8a8784817e7b7875726f6c696663605d5a5754514e4b484542, mainnet);
+        $pk = pubkey($sk);
+
+        t::eq($sk, xprv9s21ZrQH143K31xYSDQpPDxsXRTUcvj2iNHm5NUtrGiGG5e2DtALGdso3pGz6ssrdK4PFmM8NSpSBHNqPqm55Qn3LqFtT2emdEXVYsCzC2U);
+        t::eq($pk, xpub661MyMwAqRbcFW31YEwpkMuc5THy2PSt5bDMsktWQcFF8syAmRUapSCGu8ED9W6oDMSgv6Zz8idoc4a6mr8BDzTJY47LJhkJ8UB7WEGuduB);
+      });
+  });
+})

tests/multisig.minsc

@@ -0,0 +1,34 @@
+test("Multisig 2-of-2", |T| {
+  $alice_sk = tprv8ZgxMBicQKsPfJtqwiW9WhjJHPZtDo8aUbCkkcG8sjHbpZqjghF6ZJ1Tze9fUHrhYyXSNfw5VPbCKEkoFKaDRUzctbSxmxSWNfAGDonxcTG/ *;
+  $bob_sk = tprv8ZgxMBicQKsPd13DKoKTUp2N6yMvzzUq2GUXTgJ28VoRpEXEJTnXCAqXBHm6sCAMgPNR9fwjcpzCWRpV9uqu85YEtSwb4dCoBGrPP84mLrR/ *;
+
+  $alice = tpubD6NzVbkrYhZ4YmvdqNAjv7PQrR5pP8KV3toY38JSJ15zf46WK64gjndLAmKEJp4z2xhPnC6h7T5pdQ1uT9dSUJBUF5YX6tBEZpMgDytLgS5/ *;
+  $bob = tpubD6NzVbkrYhZ4WU51DSz3tDgUfzssAKfjba5JkCLKYmbpeimzvrc7NfTPMStAugvBbyrii2jQKxDofyWVt2Kfxhjd2wz7BGAjNn35HnN7u2L/ *;
+
+  $multisig = wsh($alice && $bob);
+  assert::eq(address($multisig/0), tb1q58leaajpyvm5zpr5kxpuzfqth2sy94ka2zmat7l2eezcvl355slsjlap8g);
+  log("Multisig", $multisig);
+
+  $psbt = psbt [
+    "input": [
+      "prevout": b44c2d14732744392c555f0e96f6f4bce28ea1be4dd812dbbd29450610f3a7ae:1,
+      "utxo": $multisig/0:2 BTC,
+    ],
+    "outputs": [
+      bcrt1ql8nqx3q3v7napchr6ewy4tpyq5y08ywat84pen: 1.9 BTC,
+      $multisig/1:0.05 BTC, // change back to multisig
+    ],
+  ];
+
+  assert::eq(psbt::fee($psbt), 0.05 BTC);
+
+  // $signed_both = psbt::sign($psbt, [$alice_sk, $bob_sk]);
+  $signed_alice = psbt::sign($psbt, $alice_sk);
+  $signed_both = psbt::sign($signed_alice, $bob_sk);
+
+  $tx = psbt::extract(psbt::finalize($signed_both));
+
+  t::eq($tx, tx(0x02000000000101aea7f310064529bddb12d84dbea18ee2bcf4f6960e5f552c39442773142d4cb40100000000ffffffff02802b530b00000000160014f9e603441167a7d0e2e3d65c4aac240508f391dd404b4c0000000000220020f4bf33f97b51cbb176f2ada61dc7522d67e376c911453dcde837217cc586a52203483045022100aedd28d1bcc6d204e43ba0bbe1b302ff9b407022df512014907b695cc6fb05460220015a63904700d93654fd68849ae53e3950822ea284b23be38351046caa84b731014730440220259b7e95f73adebc4d3b3c0dfdb36c21390d9a738d757ecd4c5af10a392c505802204aefd85a3a078965c063252d4de480103ddd7d01b57be7dfefca8a843948c42d014621024f68a514e61e0f54f71212a0054023193665fa49f6b8edfc8c8c98565538a500ad2102345043eedf475c5d6aae23473bc1a9e617435ee0a0061c079e04f67dcb67bd35ac00000000));
+  log("Final TX", pretty($tx));
+
+})